Každý valenční rámec sestává z jednoho nebo více členů rámce. Místo členu rámce může v rámci vystupovat též alternace členů rámce, což je seznam alternujících členů rámce, oddělených svislítkem - alternace slouží v případech, kdy některý člen rámce může být obsazen různými funktory, přestože ve všech případech jde o tentýž rámec. Člen rámce je buď obligatorní, nebo fakultativní a je tvořen právě jedním funktorem (pokud se nejedná o případ alternace) a popisem možných realizací. Souhrn popisů možných realizací u jednoho celého rámce obecně odpovídá nějaké souvislé části analytického stromu, jehož atributy uzlů nejsou plně vyplněny, resp. (budeme-li uvažovat zcela obecný případ) povolené kombinace hodnot těchto atributů jsou definovány jakýmkoli logickým výrazem, ve kterém tyto hodnoty vystupují. V PDT není nutno plné obecnosti využít, což dovoluje dekomponovat možné realizace takto:

frame := [ root_real_spec ] element_list
root_real_spec := '(' realizations ')'
element_list := element|element_alternation [ ' ' element_list ]
element_alternation := oblig_elem '|' oblig_elem [ '|' element_alternation ]

Zápis rámce začíná nepovinným zápisem seznamu přípustných realizací kořene podstromu (např. některé rámce s funktorem DPHR vyžadují, aby řídící sloveso bylo negované) uvedeným v kulatých závorkách, následovaný posloupností zápisů členů rámce, oddělených mezerou (bílým místem), případně alternací obligatorních členů rámce (zápis alternace tvoří posloupnost zápisů obligatorních členů rámce, oddělených svislítkem). Každý funktor (včetně ne-aktantů a alternací) se v zápisu rámce smí objevit nejvýše jednou. Členy rámce jsou řazeny v následujícím kanonickém pořadí (podle funktorů): ACT, CPHR, DPHR, PAT, ADDR, ORIG, EFF, BEN, LOC, DIR1, DIR2, DIR3, TWHEN, TFRWH, TTILL, TOWH, TSIN, TFHL, MANN, MEANS, ACMP, EXT, INTT, MAT, APP, CRIT, REG.

element := oblig_elem |  facult_elem 
oblig_elem := elem_spec
facult_elem := '?' elem_spec

Členy rámce jsou buď fakultativní, nebo obligatorní. Zápisu fakultativního členu rámce předchází otazník.

elem_spec := functor '(' realizations ')'
functor := 'ACT' | 'PAT' | 'ADDR' | 'EFF' | 'ORIG' | 'ACMP' | 'AIM' | 'APP' 
            | 'ATT' | 'AUTH' | 'BEN' | 'CAUS' | 'CNCS' | ' COMPL' | 'CONTRD' 
            | 'COND' | 'CPHR' | 'CPR' | 'CRIT' | 'DES' | 'DIFF' | 'DIR1' 
            | 'DIR2' | 'DIR3' | 'DPHR' | 'EXT' | 'HER' | 'INTF' 
            | 'INTT' | 'LOC' | 'MANN' | 'MAT' | 'MEANS' | 'MOD' | 'PAR' 
            | 'PARTL' | 'REG' | ' RESL' | 'RESTR' | 'RSTR' | 'SUBS' | 'TFHL'
            | 'TFRWH' | 'THL' | 'THO' | 'TOWH' | 'TPAR' | 'TSIN' | 'TTILL'
            | 'TWHEN' | 'TOWH' | 'VOCAT'

Zápis členu rámce sestává z funktoru a zápisu seznamu přípustných realizací v kulatých závorkách.

realizations := real [ ';' realizations ]

Zápisy jednotlivých přípustných realizací jsou odděleny středníkem.

real := '*' | '!' | '=' | real_spec_list [ '&' ] [ real_spec_list ]
real_spec_list := [ '^' ] real_spec [ ','  real_spec_list ] 
real_spec := ( lemma_spec [ sep ] [ morph ] | sep morph ) [ dependants ]
sep := '.' | ':'
dependants := '[' real_spec_list ']'

Zápisem realizace je buď hvězdička, zastupující obecně všechny typické realizace pro daný funktor, vykřičník, značící, že příslušný člen rámce není (nikdy) povrchově/analyticky realizován, rovnítko označující, že jde o stav (atribut is_state), nebo zápis realizace, tvořený zápisy realizací uzlů oddělených čárkou (případně znakem & - viz dále) a jejich potomků. Zápisy realizací uzlů se uvádějí v pořadí, v jakém se uzly nacházejí v analytickém stromě. Zápisy realizací potomků, nacházejících se vlevo od svého rodiče jsou od potomků nacházejících se vpravo od rodiče odděleny znakem & místo čárky. Seznam realizací potomků smí být znakem & též ukončen, a to v případě, kdy se všichni potomci nacházejí vlevo od svého rodiče.

Zápisem realizace uzlu je zápis specifikace lematu a/nebo jeho morfologických charakteristik. Není nutné, aby byly obě části přítomny současně, alespoň jedna z nich je však nutná.

V případě, že je zápis 1. realizace uvozen symbolem ^, vztahuje se realizace na rodiče uzlu řídícího členy rámce (slovesa/substantiva) místo na uzly realizující příslušný člen rámce.

Část zápisu specifikující lema je od části specifikující morfologické požadavky oddělena buď tečkou, nebo dvojtečkou. Nejsou-li uvedeny žádné morfologické požadavky, není nutné oddělovač uvádět. V takovém případě je chápán jako dvojtečka. Je-li oddělovačem tečka, znamená to, že analytický uzel odpovídající dané realizaci bude rodičem všech kořenů analytických podstromů odpovídajících realizacím synů tektogramatického uzlu představujícího člen rámce, k němuž zápis realizace náleží. Z toho vyplývá, že v rámci jedné alternativy by se mezi zápisy realizací (včetně zanořených) měl vyskytnout právě jeden obsahující tečku.

lemma_spec := LEMMA | '{' lemma_set '}' | '"' FORM '"'
lemma_set := LEMMA [ ',' lemma_set ] | LEMMA ',' '...'

Zápis specifikace lematu je tvořen buď řetězcem lematu, nebo seznamem takových řetězců uvedeným ve složených závorkách a oddělených čárkou, případně řetězcem uzavřeným do dvojitých apostrofů, vyjadřujícím přímo povrchovou formu. Zápis využívající formu namísto lemmatu se zpravidla využívá pouze v případech, kdy konkrétní povrchovou podobu realizace nelze zachytit jiným způsobem (například jedná-li se o specifický nářeční či hovorový tvar). Seznam lemat může být také ukončen čárkou a třemi tečkami, čímž je naznačeno, že nejde o úplný výčet třídy přípustných lemat, ale pouze o doposud shromážděné reprezentanty této třídy (typicky u funktoru CPHR). Řetězcem lematu se rozumí řetězec identifikující nějakou položku v morfologickém slovníku (v praxi se jedná a základní formu daného slova za níž někdy následuje ještě spojovník a číslo). Řetězec lematu (případně formy) smí obsahovat pouze alfanumerické znaky a spojovník, veškeré ostatní znaky musí být uvozeny zpětným lomítkem \. Lema pro zpětné lomítko se tedy zapíše jako \\.

morph := [ neg ] [ pos ] [ gender ] [ number ] [ case ] [ deg ]
 [ agreement ] [ tag_spec ]

Zápis morfologických požadavků tvoří zápis specifikace slovního druhu, rodu, čísla, pádu, stupně u přídavných jmen a shody, přičemž žádná z těchto položek není povinná, avšak aspoň jedna by měla být vždy přítomna. Není-li některá z položek uvedena, znamená to, že jsou přípustné všechny hodnoty. Je-li v zápisu realizace uvedeno lema, není již nutné uvádět morfologický požadavek na slovní druh, neboť ten je již lematem jednoznačně určen.

neg := '~'

Vlnka značí požadavek na to, aby v morfologické značce byl přítomen příznak pro negaci.

pos := 'a' | 'd' | 'i' | 'n' | 'u' | 'j' | 'v' | 's' | 'f' | 'c'

Slovní druh je zapsán malým písmenem:

gender := 'F' | 'M' | 'I' | 'N'

Rod je zapsán velkým písmenem:

number := 'S' | 'P'

Číslo je zapsáno velkými písmeny:

case := '1' | '2' | '3' | '4' | '5' | '6' | '7'

Pád je zapsán svým číslem.

deg := '@1' | '@2' | '@3'

Stupeň přídavného jména kvůli odlišní od pádu předchází symbol @.

agreement := '#'

Shoda v pádě, čísle a rodě s řídícím uzlem (pouze v případě, že tato kategorie u obou uzlů existuje a u závislého uzlu už to není zápisem morfologických požadavku specifikováno).

tag_spec := tag_pos '<' tag_values '>' [ tag_spec ]
tag_pos := [ '$1' | '$2' | '$3' | '$4' | '$5' | '$6' | '$7' | '$8' | '$9' |
           '$10' | '$11' | '$12' | '$13' | '$14' | '$15'
tag_values := CHAR [ tag_values ]

Pro případy, kdy výše uvedené zápisy nestačí k popisu požadavků na morfologickou značku, je možné uvést další požadavky formou výčtu hodnot povolených na konkrétních pozicích morfologické značky. Zápis požadavku na hodnotu určité pozice morfologické značky začíná symbolem $, za ním je uvedeno číslo pozice (1 až 15), a následuje řetězec uzavřený do špičatých závorek < > tvořený právě všemi znaky, které zápis na dané pozici morfologické značky povoluje. Všechny znaky vyjma písmen, číslic a spojovníku vyskytující se uvnitř špičatých závorek musejí být uvozeny zpětným lomítkem.

Valenční rámec může být i prázdný. Takový valenční rámec je zapsán jako: EMPTY.